Горит сессия, помогите!

[maxim56_90]

Горит сессия, помогите!

1. Дана матрица A(n*m) и целые числа р и q. Преобразовать матрицу А так, чтобы строка с исходным номером р непосредственно следовала за строкой с исходным номером q, сохранив порядок следования остальных строк.

2. Даны вещественные числа a,b. Значения функции записать в массив. Затем, используя значения функции, записанные в массиве вычислить значение интеграла, по формуле трапеций

I1=h*[f(a)/2+f(a+h)+f(a+2h)+…+f(a+(n-1)h)+f(b)/2],

где h=(b-a)/n, n=100.

f(x)=1/((0.5+0.1x3)√x);
a=0.1; b=2.1

На Pascal'e...

 

[Vladimir_S]

Горит, стало быть, сессия, говорите? Вообще-то первым поползновением моим было посоветовать картошку на её (сессии) пепелище посадить - говорят, хорошо растет. Эх, ну да ладно, не бить же лежачего. Держите:

CONST
 N=6;
 M=10;
VAR
 A:ARRAY[1..N] of ARRAY[1..M] of INTEGER;
 S:ARRAY[1..M] of INTEGER;
 p,q,i,j:Integer;
BEGIN
 Randomize;
 WriteLn('Initial matrix:');
 For i:=1 to N do
  begin
   For j:=1 to M do
    begin
     A[i][j]:=50-Random(100);
     Write(A[i][j]:5);
    end;
   writeln;
  end;
 Write('q (<',N,')= ');
 ReadLn(q);
 Write('p (<>',q,')= ');
 ReadLn(p);
 S:=A[p];
 if p<q then
  begin
   for i:=p+1 to q do
    A[i-1]:=A[i];
   A[q]:=S;
  end
 else
  begin
   for i:=p-1 downto q+1 do
    A[i+1]:=A[i];
   A[q+1]:=S;
  end;
 Writeln;
 WriteLn('Transformed matrix:');
 For i:=1 to N do
  begin
   For j:=1 to M do
    Write(A[i][j]:5);
   writeln;
  end;
 Readln;
END.

CONST
 a=0.1;
 b=2.1;
 n=100;
VAR
 T:ARRAY[0..n] of Real;
 S,h:Real;
 i:Integer;
Function f(x:Real):Real;
 begin
  f:=1.0/((0.5+0.1*x*x*x)*SQRT(x));
 end;
BEGIN
 h:=(b-a)/n;
 for i:=0 to n do
  T[i]:=f(a+h*i);
 S:=(T[0]+T[n])*h/2;
 for i:=1 to n-1 do
  S:=S+T[i]*h;
 Writeln('S= ',S);
 Readln;
END.

 

[maxim56_90]

Владимир, огромное спасибо!!!