Как вычислить значение аргумента Х?

[Linka]

Как вычислить значение аргумента Х?

М, собственно вопрос, как вычислить значение функции cos^2 x при значении аргумента x, от 0 до Pi/2 (0; Pi/2) с шагом Pi/90.

Ссылка удалена ?

Расчеты производить по этой формуле Ссылка удалена по разложению в ряд.

Если у кого есть свободные 6 минут, помогите с кодом, пожалуйста =)


UPD.
Извините, название темы неверно..

UPD2
Именно паскаль, спасибо! )

 

[Vladimir_S]

М, собственно вопрос, как вычислить значение аргумента x, функции cos^2 x с шагом

Ссылка удалена ?

Расчеты производить по этой формуле

Ссылка удалена

по разложению в ряд.

Если у кого есть свободные 6 минут, помогите с кодом, пожалуйста =)

Пожалуйста (если, конечно, Вас устроит Паскаль - язык Вы не указали):

VAR
 X:REAL;
 i:INTEGER;

Function SUM(Xs:REAL):REAL;
 VAR
   a:REAL;
   n:INTEGER;
 Begin
   a:=-SQR(2*Xs)/2;
   SUM:=1+0.5*a;
   n:=1;
   Repeat
    Inc(n);
    a:=-a*SQR(2*Xs)/(2*n-1)/(2*n);
    SUM:=SUM+0.5*a;
   Until Abs(a)<1E-7;
 End;

BEGIN
 For i:=0 TO 45 DO
  Begin
    X:=Pi*i/90;
    WriteLn(i:2,'*Pi/90', SUM(X):10:5, SQR(Cos(X)):10:5);
  End;
 ReadLn;
END.

 

[Linka]

Vladimir_S, спасибо за ответ.
Но выдает ошибку: Stack overflow error.. (

 

[Vladimir_S]

Vladimir_S, спасибо за ответ.
Но выдает ошибку: Stack overflow error.. (

Ч-черт, гнусная штука! У меня работает безупречно, погонял. Поэтому с отладкой помочь не могу. Попробуйте сами.

 

[Vladimir_S]

Vladimir_S, спасибо за ответ.
Но выдает ошибку: Stack overflow error.. (

Попробуйте такой вариант функции:

Function SUM(Xs:REAL):REAL;
 VAR
   a,S:REAL;
   n:INTEGER;
 Begin
   a:=-SQR(2*Xs)/2;
   S:=1+0.5*a;
   n:=1;
   Repeat
    Inc(n);
    a:=-a*SQR(2*Xs)/(2*n-1)/(2*n);
    S:=S+0.5*a;
   Until Abs(a)<1E-7;
   SUM:=S;
 End;

Надеюсь, поможет.

 

[Linka]

Помогло +)
Спасибо!

 

[Linka]

Вопрос, а зачем 2 последнтие колонки одинаковые ? )

 

[Vladimir_S]

Помогло +)
Спасибо!

Уф-ф! (вздох облегчения)

 

[Vladimir_S]

Вопрос, а зачем 2 последнтие колонки одинаковые ? )

А для проверки: первая - это вычисление функции через разложение в ряд, а вторая - просто значения Cos²(x). Там же в операторе вывода всё прописано.

 

[Linka]

Спасибо еще раз.

Прошу прощения, за возможно глупый вопрос, но имеет ли место быть в этом решении рекуррентная формула ?

 

[Vladimir_S]

Спасибо еще раз.

Прошу прощения, за возможно глупый вопрос, но имеет ли место быть в этом решении рекуррентная формула ?

В какой-то мере да - каждый следующий член ряда вычисляется из предыдущего.

 

[Linka]

Уважаемый Владимир. У меня к вам еще один вопрос, уже не совсем по паскалю, а связанный непосредственно с математикой. Прошу прощения за большой пост, но не знаю как иначе объяснить.

Проблема, в том, что оператор вычисления, нужно вывести из рекуррентной формулы.

Приведу пример, который был дан как образец к заданию:
Ссылка удалена

вот ниже выкладываю, что вышло у меня после разложения в ряд (сверху само задание, что в самом первом сообщении...):
Ссылка удалена
Ссылка удалена

И полученная рекуррентная формула, отличается от нашего оператора
a:=-a*SQR(2*Xs)/(2*n-1)/(2*n);

Не могли, бы вы описать, как получился наш оператор и почему моя формула неверна ? Спасибо большущее сразу

 

[Vladimir_S]

И полученная рекуррентная формула, отличается от нашего оператора
a:=-a*SQR(2*Xs)/(2*n-1)/(2*n);

Не могли, бы вы описать, как получился наш оператор и почему моя формула неверна ? Спасибо большущее сразу

Собственно, отличаются они знаменателем. Вот давайте его и рассмотрим.
В знаменателе исходного выражения стоит величина (2n)! . Нарисуем, для наглядности, таблицу:

   n                       (2n)!
   1                         2*1
   2                     4*3*2*1
   3                 6*5*4*3*2*1
   4             8*7*6*5*4*3*2*1

Таким образом, ясно, что для того, чтобы получить следующее (n-ое) значение знаменателя, нужно предыдущее умножить на 2n*(2n-1). Что в программе и сделано.

 

[Linka]

Владимир, спасибо ) Вы мне очень помогли )

И еще если позволите, два, на сей раз последних, вопроса:

1.Что делает эта строка ?

Until Abs(a)<1E-7;

2.Чтобы в третьем столбце выводился порядковый номер элемента в ряде, надо менять всю структуры программы ? Как я понимаю, функция может только одно какое-то значение возвращать, и n из нее нельзя показать ?

 

[Vladimir_S]

Владимир, спасибо ) Вы мне очень помогли )

И еще если позволите, два, на сей раз последних, вопроса:

1.Что делает эта строка ?

Until Abs(a)<1E-7;

2.Чтобы в третьем столбце выводился порядковый номер элемента в ряде, надо менять всю структуры программы ? Как я понимаю, функция может только одно какое-то значение возвращать, и n из нее нельзя показать ?

1. Эта строка прерывает вычисление: ведь ряд - это бесконечная сумма, значит нужен критерий, по которому можно остановить расчет. Я выбрал такой: вычисление останавливается, когда следующий член ряда (и все остальные, соответственно) оказывается по абсолютной величине меньшим наперед заданного малого числа, в данном случае (с потолка) 1E-7. Конечно, можно и более "научно", но для этого надо вспоминать теорию остаточных членов функциональных рядов, а мне лень.
2. Не очень понятен вопрос. В вычислении функции для каждого значения аргумента участвуют формально ВСЕ члены ряда со ВСЕМИ номерами, от 1 до бесконечности. В данном случае бесконечность заменена на некое максимальное значение n, которое получается при "срабатывании" условия, описанного в п.1. Вас интересует его вывести?
Если да, то, действительно, придется несколько изменить программу, в частности, заменить функцию процедурой. Как-то так:

VAR
 X,SUM:REAL;
 i,Nmax:INTEGER;

Procedure SUM_CALC(Xs:REAL; var S:REAL; var n:INTEGER);
 VAR
   a:REAL;
 Begin
  a:=-SQR(2*Xs)/2;
  S:=1+0.5*a;
  n:=1;
  Repeat
   Inc(n);
   a:=-a*SQR(2*Xs)/(2*n-1)/(2*n);
   S:=S+0.5*a;
  Until Abs(a)<1E-7;
 End;

BEGIN
 For i:=0 TO 45 DO
  Begin
   X:=Pi*i/90;
   SUM_CALC(x, SUM, Nmax);
   WriteLn(i:2,'*Pi/90', SUM:10:5, SQR(Cos(X)):10:5, Nmax:5);
  End;
 ReadLn;
END.