Массивы

[LASSTIRE]

Массивы

Здраствуйте,подскажите с решением.

В одномерном массиве,состоящем из n вещественных элементов,вычислить:
Произведение отрицательных элементов массива;
Сумму положительных элементов массива, расположенных до максимального элемента ;
изменить порядок следования элементов в массиве на обратный.

решение нужно в паскале.

 

[LASSTIRE]

uses crt;
type mas = array[1..255] of integer;
var A: mas;
i,n,proiz: integer;
begin clrscr;
randomize;
write('Введите n: ');
readln; writeln;
writeln('Массив: ');
for i:=1 to n do begin
A:=random(100)-50;
write(A:4);
if A<0 then proiz:=proiz*A;
end;
writeln; writeln;
writeln('произведение отрицательных: ',sum);
end.

первая часть вроде получилась, помогите дальше

 

[Vladimir_S]

первая часть вроде получилась, помогите дальше

Не получилась - куча ошибок.

uses crt;
type mas = array[1..255] of integer;
var A: mas;
i,n,proiz: integer;

1. В условии задачи массив должен быть вещественным - значит такой тип и надо задавать.
2. Переопределять пользовательский тип вовсе в данном случае лишнее. То есть можно, конечно, и так - только вот зачем?
3. Не введена переменная суммы.
С учетом замечаний, раздел описания переменных формулируем так:

[COLOR=Red]uses crt;[/COLOR]
[COLOR=Red]var 
 A,B: array[1..500] of real;
 i,n,Imax: integer;
 proiz: Extended;[/COLOR]
 [COLOR=Red]sum,Max: real;
[/COLOR]

Введены еще переменные для поиска номера максимального элемента массива (Max, Imax) и массив B - в нем элементы будут в обратном порядке. Кроме того, поскольку произведение может оказаться очень большим числом, формат этой переменной лучше дать расширенный. Между прочим, в Вашем варианте формат "Integer" для proiz заведомо "тесен", тут нужно хотя бы LongInt - но и его может не хватить.

begin clrscr;
randomize;
write('Введите n: ');
readln; writeln;
writeln('Массив: ');
for i:=1 to n do begin
A:=random(100)-50;
write(A:4);
if A<0 then proiz:=proiz*A;
end;

С учетом замечания о типе данных массива заполнение и вывод нужно изменить. Кроме того, пропущено одно важнейшее действие: присвоение переменной proiz исходного значения 1. А выведено почему-то вовсе значение sum, т.е. переменной, которая и не объявлена даже.

[COLOR=Red]begin 
 clrscr;
 randomize;
 write('Введите n: ');
 readln(n); 
 writeln;
 writeln('Массив: ');
 proiz:=1;
 for i:=1 to n do 
  begin
   A[i]:=random*100-50;
   write(A[i]:8:2);
   if A[i]<0 then proiz:=proiz*A[i];
  end;
 writeln; 
 writeln('произведение отрицательных: ',proiz:25:2);
 writeln;
[/COLOR]

Так, ну вроде с произведением разобрались. Поехали дальше.
Требуется найти номер максимального элемента и сосчитать сумму положительных элементов, расположенных до него. Это просто:

 [COLOR=Red]Imax:=1;
 Max:=A[1];
 for i:=2 to n do
  if A[i]>Max then
   begin
    Max:=A[i];
    Imax:=i;
   end;
 sum:=0;
 for i:=1 to Imax do
  if A[i]>0 then sum:=sum+A[i];
 writeln('сумма положительных до максимального: ',sum:12:2);[/COLOR]
 [COLOR=Red]writeln;[/COLOR]

Так, с этим тоже управились. Осталось перевернуть порядок следования элементов исходного массива. Нет ничего проще:

 [COLOR=Red]for i:=1 to n do
  begin
   B[i]:=A[n-i+1];
   write(B[i]:8:2);
  end;
 readln;
end.[/COLOR]

Всё! Осталось только сшить программу.

 

[LASSTIRE]

Не ожидал такого широкого ответа,
спасибо Вам ,Vladimir_S , огромное за объяснение ,за то что все подробно расписали.