• Добро пожаловать на компьютерный форум Tehnari.ru. Здесь разбираемся с проблемами ПК и ноутбуков: Windows, драйверы, «железо», сборка и апгрейд, софт и безопасность. Форум работает много лет, сейчас он переехал на новый движок, но старые темы и аккаунты мы постарались сохранить максимально аккуратно.

    Форум не связан с магазинами и сервисами – мы ничего не продаём и не даём «рекламу под видом совета». Отвечают обычные участники и модераторы, которые следят за порядком и качеством подсказок.

    Если вы у нас впервые, загляните на страницу о форуме и правила – там коротко описано, как задать вопрос так, чтобы быстро получить ответ. Чтобы создавать темы и писать сообщения, сначала зарегистрируйтесь, а затем войдите под своим логином.

    Не знаете, с чего начать? Создайте тему с описанием проблемы – подскажем и при необходимости перенесём её в подходящий раздел.
    Задать вопрос Новые сообщения Как правильно спросить
    Если пришли по старой ссылке со старого Tehnari.ru – вы на нужном месте, просто продолжайте обсуждение.

Помогите с контрольными по программированию на Паскале

  • Автор темы Автор темы EVO_X
  • Дата начала Дата начала
E

EVO_X

Новые
Регистрация
26 Янв 2013
Сообщения
946
Реакции
5
Баллы
0
Помогите с контрольными по программированию на Паскале

Здравствуйте, помогите сделать контрольные на паскале, если можно с пояснениями. Нужно для допуска к зачету.
 

Вложения

  • 4.png.webp
    4.png.webp
    32.3 KB · Просмотры: 109
  • 5.png.webp
    5.png.webp
    36.1 KB · Просмотры: 116
  • 6.png.webp
    6.png.webp
    40 KB · Просмотры: 103
EVO_X написал(а):
Здравствуйте, помогите сделать контрольные на паскале, если можно с пояснениями. Нужно для допуска к зачету.
Нажмите для раскрытия...
Интересно, что Вы будете делать на зачете... ну да Вам видней. Насчет пояснений - спрашивайте, если что-то непонятно будет.

Первое задание. Программа содержит обе подпрограммы (функцию и процедуру)
Код: 
Var
 n:Byte;

Function Test3(M:Byte):Boolean;
var
 M1,Sum:Byte;
begin
 M1:=M;
 Sum:=0;
 repeat
  Sum:=Sum+(M1 mod 10);
  M1:=M1 div 10;
 until M1=0;
 Test3:=(Sum mod 3)=0;
end;

Procedure Print_Triangle(M:Byte);
var
 i,j:Byte;
begin
 for i:=1 to M do
  begin
   for j:=1 to i do write(j:4);
   writeln;
  end;
end;

Begin
 Write('n = ');
 Readln(n);
 Writeln(Test3(n));
 Writeln;
 Print_Triangle(n);
 Readln
End.
 
Второе задание. Тоже обе программы объединены:
Код: 
Const
 M=10;
 N=12;

Var
 A:Array[1..M] of Byte;
 B:Array[1..M,1..N] of Byte;
 i,j,Num:Byte;

Begin
 Randomize;
 for i:=1 to M do
  begin
   A[i]:=Random(256);
   write(A[i]:4);
  end;
 Writeln;
 Writeln;
 Writeln(' i     A[i]');
 Num:=0;
 for i:=2 to M-1 do
  if A[i]<(A[i-1]+A[i+1])/2 then
   begin
    Inc(Num);
    Writeln(i:2,A[i]:8);
   end;
 Writeln;
 Writeln(Num, ' elements');
 Writeln('Press "Enter" to continue');
 Readln;

 for i:=1 to M do
  begin
   for j:=1 to N do
    begin
     B[i,j]:=Random(256);
     Write(B[i,j]:4);
    end;
   Writeln;
  end;
 Writeln;
 Writeln;
 Writeln('Minimal elements:');
 Writeln(' i      El');
 for i:=1 to M do
  begin
   A[i]:=B[i,1];
   for j:=2 to N do
    if B[i,j]<A[i] then A[i]:=B[i,j];
   Writeln(i:2,A[i]:8);
  end;
 Readln
End.
 
Третье задание:
Код: 
Const
 Eps=0.00001;
 Nmax=200;

Function S(z:real):Real;
var
 a,Sum:real;
 k:byte;
begin
 k:=0;
 a:=(Pi/2)/3*z*z*z;
 Sum:=a;
 Repeat
  Inc(k);
  a:=-a*Sqr(Pi/2)/(2*k)/(2*k+1)*(4*k-1)/(4*k+3)*Sqr(Sqr(z));
  Sum:=Sum+a;
 Until (Abs(a)<Eps) or (k>Nmax);
 S:=Sum;
end;

Var
 i:Byte;

Begin
 for i:=0 to 10 do
  writeln(0.5*i:3:1,S(0.5*i):12:3);
 Readln
End.
 
Спасибо огромное!!!
С первым понял, вроде. Во втором как я понял в одномерном массиве число символов постоянно и равно 10?
Сделал для задаваемых M и N. остальное тоже вроде пока понятно.
 
Также нужна программа для вычисления ряда Тейлора для ln(1+x). Мы на парах делали для вычисления sin(x). Но для логарифма у меня так и не получается. Могу скинуть синус в виде примера, чтоб вы поняли, что мне нужно для логарифма.
 
EVO_X написал(а):
Также нужна программа для вычисления ряда Тейлора для ln(1+x). Мы на парах делали для вычисления sin(x). Но для логарифма у меня так и не получается. Могу скинуть синус в виде примера, чтоб вы поняли, что мне нужно для логарифма.
Нажмите для раскрытия...
Не, не надо синуса. У нас подобных задач рассмотрена куча. Сформулируйте четко задание и лучше выложите свои попытки решения.
 
Vladimir_S написал(а):
Сформулируйте четко задание и лучше выложите свои попытки решения.
Нажмите для раскрытия...
Вот я не знаю как четко сформулировать, преподаватель из головы сказал что должна делать программа.
Но попробую. Нужно разложить ln(1+x) в ряд Тейлора и найти сумму(вот это я сделал программа считает ее нормально), затем сравнить ее с табличным значением, если все нормально, то делать дальше.
Дальше нужно, при задаваемом отрезке(его начального и конечного значений) и шаге по этому отрезку построить таблицу значений данной функции и записать эти значения в блокнот.
Далее уже собственноручно скопировать эти значения из блокнота и вставить их в эксель и построить график по этим точкам, должен получиться логарифм.

Vladimir_S написал(а):
Не, не надо синуса.
Нажмите для раскрытия...
Его в качестве примера хотел показать.
 
Не знаю как текст программы вставлять, отправляю так свои начала по логарифму.


var n:integer;
a,x,s,lnmy:real;
begin
writeln ('x?');
readln(x);
if not ((x<=1) and (x>-1)) then
writeln('Введенный х не попадает в область значений')
else
begin
a:=x; s:=x; n:=1;
repeat a:=-(a*x*n)/(n+1);
s:=s+a;
n:=n+1;
until abs(a)<1e-7;
lnmy:=s;
writeln ('ln(1+x)=', lnmy,' ',ln(1+x));
end;
end.
 
EVO_X написал(а):
Не знаю как текст программы вставлять, отправляю так свои начала по логарифму.
Нажмите для раскрытия...
Ну так что ж, у Вас почти всё сделано, только нужно вывод в файл добавить для дальнейшей работы. Пожалуйста:
Код: 
Var
 n,i:integer;
 a,x,S:real;
 f:Text;

Begin
 Assign(f,'Ln.txt');
 Rewrite(f);
 for i:=-9 to 9 do
  begin
   x:=0.1*i;
   a:=x;
   S:=a;
   n:=1;
   repeat
    n:=n+1;
    a:=-a*(n-1)/n*x;
    S:=S+a;
   until Abs(a)<1E-7;
   Writeln(x:4:1,S:15:5,Ln(1+x):15:5);
   Writeln(f,x:4:1,S:15:5);
  end;
 Close(f);
 Readln
End.
 
Логарифм получился, осталось сделать чтобы границы отрезка и шаг можно было самому забивать:)
 

Вложения

  • логарифм.webp
    логарифм.webp
    1.7 KB · Просмотры: 75
Что-то не получается, что не пробовал, пишет нельзя применять integer к real...:(
 
Сначала убрал x:=0.1*i; и вместо -9 и 9 поставил переменные, которые ранее задаются. Переменные вводил в виде десятичных дробей, т. к. формула для суммирования действует на полуинтервале (-1;1].
Потом пробовал, чтобы введеные границы в виде десятичной дроби умножились на 10 потом вместо -9 и 9 соответственно шли дальше по вашей программе.
Ни там, ни там ничего не получилось...
 
EVO_X написал(а):
Сначала убрал x:=0.1*i; и вместо -9 и 9 поставил переменные, которые ранее задаются. Переменные вводил в виде десятичных дробей
Нажмите для раскрытия...
Лихо! А то, что индекс цикла может быть только целым числом - это Вам как? Мимо?
EVO_X написал(а):
формула для суммирования действует на полуинтервале (-1;1]
Нажмите для раскрытия...
На самом деле - в интервале (-1;1). Т.е. формально плюс единица допускается, но, поскольку ряд сходится очень медленно, при той дикой (одна десятимиллионная) точности при х=1 получается такое число слагаемых, которое выходит за разрядную сетку и возникает ошибка. Поэтому лучше до +1 не доходить.
Вот вариант:
Код: 
Var
 n,i,M:integer;
 a,x,S,Step:real;
 f:Text;

Begin
 Assign(f,'D:\Ln.txt');
 Rewrite(f);
 Write('Step = ');
 Readln(Step);
 M:=Trunc(2.0/Step);
 x:=-1;
 for i:=1 to M do
  begin
   x:=x+Step;
   a:=x;
   S:=a;
   n:=1;
   repeat
    n:=n+1;
    a:=-a*(n-1)/n*x;
    S:=S+a;
   until Abs(a)<1E-7;
   Writeln(x:6:3,S:15:5,Ln(1+x):15:5);
   Writeln(f,x:6:3,S:15:5);
  end;
 Close(f);
 Readln
End.
 
В этой программе мы задаем шаг, а промежуток тот же что и в первой программе?
 
EVO_X написал(а):
В этой программе мы задаем шаг, а промежуток тот же что и в первой программе?
Нажмите для раскрытия...
А что, и его менять надо? Ну пожалуйста: задаются нижняя и верхняя границы, а также шаг:
Код: 
Var
 n,i,M:integer;
 a,x,S,Step,mn,mx:real;
 f:Text;

Begin
 Assign(f,'Ln.txt');
 Rewrite(f);
 Write('Minimal value = ');
 Readln(mn);
 Write('Maximal value = ');
 Readln(mx);
 Write('Step = ');
 Readln(Step);
 M:=Trunc((mx-mn)/Step)+2;
 x:=mn-step;
 for i:=1 to M do
  begin
   x:=x+Step;
   a:=x;
   S:=a;
   n:=1;
   repeat
    n:=n+1;
    a:=-a*(n-1)/n*x;
    S:=S+a;
   until Abs(a)<1E-7;
   Writeln(x:6:3,S:15:5,Ln(1+x):15:5);
   Writeln(f,x:6:3,S:15:5);
  end;
 Close(f);
 Readln
End.
 
Во, то что нужно:)
Еще добавлю чтобы при задании значений промежутка не выходить за (-1,1)
 
Войдите или зарегистрируйтесь для ответа.
Назад
Сверху